A função SE faz uma pergunta e devolve uma resposta diferente para sim e para não. A estrutura é sempre esta:
=SE(pergunta; resposta_se_sim; resposta_se_não)
Um exemplo que resolve na hora — aprovar quem tirou 7 ou mais:
=SE(B2>=7; “Aprovado”; “Reprovado”)
Se a nota em B2 for 7 ou maior, aparece Aprovado. Qualquer outro caso, Reprovado.
As três partes
Texto sempre entre aspas. Número, nunca.
A pergunta precisa ser algo que só pode dar certo ou errado — uma comparação. B2>=7 é uma pergunta válida: ou a nota é maior ou igual a 7, ou não é.
A resposta se sim e a resposta se não podem ser texto, número, outra fórmula ou até uma referência a outra célula.
Aspas só no texto. “Aprovado” leva aspas porque é texto. 7 não leva, porque é número. Colocar aspas num número transforma ele em texto, e aí as comparações param de funcionar direito.
Os operadores de comparação
A pergunta é montada com um destes seis sinais:
O <> significa “diferente de” — é o menos conhecido e um dos mais úteis.
Alguns exemplos de perguntas válidas:
- B2=”Sim” — a célula tem exatamente a palavra Sim
- B2>1000 — o valor passou de mil
- B2<>”” — a célula não está vazia
- B2=C2 — as duas células têm o mesmo conteúdo
SE aninhado: mais de duas respostas
Quando você precisa de três ou mais saídas, coloca um SE dentro do outro. Cada SE novo entra no lugar da resposta “se não”.
Convertendo nota em conceito:
=SE(B2>=9;”A”; SE(B2>=7;”B”; SE(B2>=5;”C”;”D”)))
A leitura é em cascata: é 9 ou mais? Se sim, A. Se não, é 7 ou mais? Se sim, B. Se não, é 5 ou mais? Se sim, C. Se não, D.
A ordem não é opcional
Este é o erro que mais aparece em SE aninhado, e ele não dá mensagem nenhuma — só devolve o conceito errado.
A mesma lógica em duas ordens, com resultados diferentes.
O Excel para no primeiro teste que der verdadeiro e nem olha o resto. Se você começa pelo critério mais fácil, todo mundo passa nele e os testes seguintes viram enfeite.
A regra: comece sempre pelo mais exigente e vá afrouxando.
SES: a versão sem aninhamento
Se a sua versão do Excel tiver, o SES faz a mesma coisa sem as caixas dentro de caixas:
=SES(B2>=9;”A”; B2>=7;”B”; B2>=5;”C”; VERDADEIRO;”D”)
É pergunta e resposta, aos pares, até acabar. O VERDADEIRO no fim funciona como “em qualquer outro caso” — é o equivalente ao último “se não” do SE aninhado.
Muito mais fácil de ler e de corrigir. Mas atenção: a ordem continua importando exatamente do mesmo jeito, e o SES só existe no Microsoft 365 e no Excel 2019 em diante.
Testar duas coisas ao mesmo tempo: E e OU
Para exigir que duas condições sejam verdadeiras juntas, use o E:
=SE(E(B2>=7; C2>=75); “Aprovado”; “Reprovado”)
Aqui o aluno precisa de nota 7 e frequência 75. Falhando em qualquer uma, reprova.
Para aceitar qualquer uma das duas, use o OU:
=SE(OU(B2>=9; C2=100); “Destaque”; “Normal”)
Nota 9 ou frequência total já garante o destaque.
Os erros mais comuns
Esquecer as aspas no texto
=SE(B2>=7; Aprovado; Reprovado) devolve #NOME?. Sem aspas, o Excel acha que Aprovado é o nome de uma função ou de um intervalo, procura, não encontra, e reclama.
Comparar número com texto
Se a nota foi colada de outro sistema, ela pode estar guardada como texto. Aí B2>=7 dá falso mesmo quando a célula mostra 9, porque o Excel não compara texto com número. O sinal é o alinhamento: número alinha à direita, texto à esquerda.
Confiar em célula vazia
Célula vazia vale zero numa comparação numérica. Então =SE(B2>=7;”Aprovado”;”Reprovado”) marca Reprovado para quem simplesmente ainda não tem nota. Se isso importa, teste o vazio antes:
=SE(B2=””;”Sem nota”; SE(B2>=7;”Aprovado”;”Reprovado”))
Aninhar demais
O Excel aceita até 64 SE encadeados, mas a partir do quarto ou quinto ninguém mais consegue ler a fórmula — nem você daqui a dois meses. Passando disso, use SES, ou monte uma tabela de faixas e busque nela com PROCV.
Como fazer PROCV passo a passoArrastar a fórmula
Quando o SE compara com uma célula fixa — uma meta, um limite, uma taxa —, essa referência precisa de $:
=SE(B2>=$E$1; “Bateu a meta”; “Abaixo”)
Sem o $, ao arrastar para baixo a referência da meta escorrega para E2, E3, que estão vazias. E como vazio vale zero, todo mundo passa a bater a meta.
Como travar célula com o F4Resumindo
- =SE(pergunta; se_sim; se_não) — sempre três partes
- Texto entre aspas, número sem aspas
- <> significa diferente de, e <>”” significa não está vazio
- No SE aninhado, comece pelo critério mais exigente
- O Excel para no primeiro teste verdadeiro e ignora o resto
- Use E quando as duas condições precisam valer; OU quando basta uma
- Célula vazia vale zero — teste B2=”” antes se isso atrapalhar
- Passando de quatro SE encadeados, troque por SES ou por uma tabela com PROCV
A referência oficial, com a lista completa de armadilhas do aninhamento:
Documentação da Microsoft
